Mainframe Utility: CA11TABL

/**********************************************************************
/* UTILITY: CA11TABL                                                  *
/* AUTHOR: DAVID LEIGH                                                *
/* FUNCTION: WHEN LOOKING AT A CA11 OUTPUT SCREEN IN ISPF, IF YOU     *
/*           INVOKE THIS UTILITY, IT WILL COPY TABLE CA11ITBL TO A    *
/*           FLAT FILE WITH A TIME/DATE STAMP.                        *
/**********************************************************************
PROC 0 HELP
/*** CHECK THE DEBUG SWITCH ***/
ISPEXEC VGET DBGSWTCH PROFILE
IF &DBGSWTCH = ON THEN +
    CONTROL MSG LIST CONLIST SYMLIST NOFLUSH NOPROMPT ASIS
ELSE +
    CONTROL NOMSG NOLIST NOFLUSH NOPROMPT ASIS
IF &HELP = HELP THEN GOTO HELPSEC

/**********************************************************************
/* SET UP THE OUTPUT DATASET WITH A TIME DATE STAMP                   *
/**********************************************************************
SET D = &STR(D)+
        &SUBSTR(1:2,&STR(&SYSSDATE))+
        &SUBSTR(4:5,&STR(&SYSSDATE))+
        &SUBSTR(7:8,&STR(&SYSSDATE))
SET T = &STR(T)+
        &SUBSTR(1:2,&STR(&SYSTIME))+
        &SUBSTR(4:5,&STR(&SYSTIME))+
        &SUBSTR(7:8,&STR(&SYSTIME))
SET TEMPTABL = &STR(&SYSUID..TEMP.CA11TABL.&D..&T)
DELETE '&TEMPTABL'
FREE DDNAME(ISPFILE)
ALLOCATE DDNAME(ISPFILE) DSN('&TEMPTABL') +
         NEW CATALOG +
         UNIT(SYSDA) VOLUME(WRK$$$) +
         SPACE(1,1) TRACKS RELEASE +
         RECFM(F B) LRECL(80) BLKSIZE(23440) DSORG(PS)

/**********************************************************************
/* UNLOAD THE ISPF TABLE                                              *
/**********************************************************************
ISPEXEC FTOPEN
ISPEXEC FTINCL CA11TABL
SET SAVECC = &LASTCC
ISPEXEC FTCLOSE
FREE DDNAME(ISPFILE)
IF &SAVECC > 0 THEN +
    DO
        ISPEXEC VGET ZERRLM
        SET ZEDSMSG = &STR(TABLE CC: &SAVECC)
        SET ZEDLMSG = &STR(&ZERRLM)
        ISPEXEC SETMSG MSG(UTLZ001)
    END
ELSE +
    ISPEXEC EDIT DATASET('&TEMPTABL')

EXIT

/**********************************************************************
/* DISPLAY ANY "HELP" WHICH IS AVAILABLE FOR THIS UTILITY             *
/**********************************************************************
HELPSEC: +
ISPEXEC SELECT PGM(ISPTUTOR) PARM(HELPSHEL)
SET ZEDLMSG = &STR(*** HELP DISPLAYED FOR CA11TABL UTILITY +
                   *** NO PROCESSING PERFORMED ***)
ISPEXEC SETMSG MSG(UTLZ000)
EXIT
            

 CA11TABL allows the user to "capture" the contents of the CA11 ISPF interface
 output.  When you use the CA11 ISPF interface, the results of each command are
 placed in a temporary ISPF table named CA11ITBL.

 When you are viewing the results in the CA11 ISPF interface, you type TSO
 CA11TABL on the command line and press .  The contents of CA11ITBL are
 dumped into an FB 80 sequential file with the name format of
 userid.TEMP.CA11TABL.date.time.  where "date.time" is a current time/date
 stamp.

 Once the table is dumped into the file, you are taken into an ISPF edit session
 on the file.  From here, you may use this file like any other file.  Note:  the
 file is placed on "work" DASD, so it will be scratched at night.  It would be
 up to you to save any contents for longer rentention.